Publication grade nested regressions table in Stata | asdocx

asdocx can create three types of regression tables. The first type is the detailed table that combines key statistics from the Stata’s regression output with some additional statistics such as mean and standard deviation of the dependent variable etc. This table is the default option in asdocx. The second table is the nested table that nests more than one regressions in one table. The third table is the wide table that reports regression components in a wide or row format. In this post, I discuss the nested tables, their options, and examples.

syntax

[bysort varname :] asdocx depvar indepvars [if] [in], [asdocx_options 
                  regression_options]

Following is a list of asdocx options that are available with the nested regressions:

1. Default case

---

The option nested or nest invokes the creation of nested regression tables. Without this option, the default (detailed regression) table is created by asdocx. Let us create our first nested regression table.

* Load some example data
sysuse auto, clear 
		
* Add first regression to the nested model
asdocx reg price trunk mpg, nest replace 

* Add second regression to the nested model
asdocx reg price trunk mpg weight, nest 

2. Report t-statistics, standard errors, p-values or CI

---

Option rep() is used in combination with option nest for reporting t-values, standard errors, p-values or confidence intervals with each of the regression coefficient. Use rep(t) to report t-statistics, rep(p) to report p-values, and rep(se) to report standard errors, and rep(ci) to report confidence intervals. The default option is rep(se). Please note that option rep(t),  rep(p) and rep(ci) will work only when used at the start of the nested table. This is the case either:

(i) when option replace is used or

(ii) the nested table is started for the first time.

* Load some example data
sysuse auto, clear 
		
* Report t-statistics with option rep(t) 
asdocx reg price trunk mpg, nest replace rep(t)

* Add second regression to the nested model
asdocx reg price trunk mpg weight, nest rep(t) 

3. Report ci, se, t- or p-values sideways

---

Option sideways is used to report t-statistics, standard errors, p-values, or confidence intervals to the right-side of the regression coefficients. The default setting is to report them below the coefficients.  In the following examples, I am creating a nested table with the following specifications.

Regression table: two logit nested regressions : option nest

Coefficients: exponentiated / odd ratios : option eform

Significance statistics: confidence interval using option rep(ci)

Placement of the significance statistics : to the right-side of the coefficients: option sideways

Variable names: reporting labels instead of names : option label

Level of confidence: 99% : option level(99)

* Load example data
 webuse lbw
 asdocx logit low age lwt i.race smoke ptl, eform nest ///
        sideways rep(ci) label level(99) replace

 asdocx logit low age lwt i.race smoke ptl ht ui, eform ///
        nest sideways rep(ci) label level(99)

4. Report variable labels

---

By default, asdocx writes variable names as the row headers. Option label can be used to report variable labels instead of variable names.

* Load some example data
sysuse auto, clear 
		
* Add first regression to the nested model
asdocx reg price trunk mpg, nest label replace 

* Add second regression to the nested model
asdocx reg price trunk mpg weight, nest label 

5. Add statistics from e()

---

Option stat() can be used to report additional regression statistics that are stored in macro e(). The e() macros are available after running a regression model. Since asdocx runs regression models below the surface, these macros are obtained by asdocx and can be reported by providing the macro names in option stat() without the e() part.  For example, stat(rmse rss) will report the RMSE and RSS of the model. Please note that these statistics will be reported only if they are available in the e() macro. If they are not available, asdocx will highlight it as an error and report the given statistic as missing. All e() macros can be listed by typing  ereturn list in Stata command window after a regression model. See the following example where I report the RMSE and adjusted r-squared, which are available in the e(rmse) and e(r2_a) macros, respectively.

* Add first regression to the nested model
asdocx reg price trunk mpg, nest stat(rmse r2_a) replace

* Add second regression to the nested model
asdocx reg price trunk mpg weight, nest stat(rmse r2_a)

6. Drop or keep variables

---

keep(varlist) and drop(varlist) are alternatives; they specify coefficients to be included or omitted from the table. The default is to display all coefficients. In the following example, I shall exclude all year and industry dummies from the regression table; however, these dummies will still be included in the regression models. Please note that the prefix i. is used for factor variables. If a variable is not a factor variable, it will be written without the i. prefix.

* Load Data
use http://fintechprofessor.com/regdata.dta, clear

* Add first regression
asdocx reg y x1 x2 x3 i.year i.location, nest drop(i.year i.location) replace

* Add another regression
asdocx reg y x1 x2 x4 i.year i.location, nest drop(i.year i.location)

Start a new table with option reset

Option reset causes “asdocx” to make a new nested table, i.e., instead of appending to the existing nested table, option reset will start a new table in the existing file.

* Load data from the web

webuse highschool
‎
* First regression
asdocx regress weight height, nest replace
‎
* Add a second regression to the same nested model
asdocx regress weight height state , nest

Next we are going to add the option reset to start a new nested table within the same document

* Start a new nested model with option 'reset'

asdocx regress height sex , nest reset
‎
* Add a second regression the second nested model
asdocx regress height sex state , nest